node-fftcg/backend/routes.coffee

# node libraries
#(require 'debug').enable 'routes'
logger = (require 'logging').default 'routes'
path = (require 'path')

# my libraries
FFTCGDB = (require './db')
FFTCGSESSION = (require './session')

# open fftcg.db (persistent data)
fftcgdb = new FFTCGDB path.resolve(__dirname, 'fftcg.db'), true
# open session storage (volatile data)
session = new FFTCGSESSION

module.exports = [
# test
  url: '/test'
  method: 'POST'
  handler: (request, reply) ->
    logger.info 'Cookies', request.cookies
    logger.info 'Body', request.body
    logger.info 'Query', request.query
    logger.info 'Params', request.params

    reply.setCookie 'foo', 'foo'
    reply.send
      hello: 'world'
,
# register user
  url: '/user/register'
  method: 'POST'
  handler: (request, reply) ->
    fftcgdb.register request.body.login, request.body.password
      .then (user) ->
        # registration successful
        reply.send
          status: 'ok'
          user: user.user
          login: user.login

      .catch (err) ->
        # registration failed
        reply.send
          status: 'fail'
          text: err
,
# log in user
  url: '/user/login'
  method: 'POST'
  handler: (request, reply) ->
    session_id = request.cookies.session ? ''

    new Promise (resolve, reject) ->
      session.check session_id
        .then (user) ->
          logger.debug "user '#{user.login}' resumed session '#{session_id}'"
          resolve user

        .catch ->
          fftcgdb.login request.body.login, request.body.password
            .then (user) ->
              # login successful: start new session
              session.start user
                .then (session_id) ->
                  logger.debug "user '#{user.login}' logged into session '#{session_id}'"
                  reply.setCookie 'session', session_id
                  resolve user

            .catch (err) ->
              logger.info "failed login for '#{request.body.login}'"
              # login failed
              reply.send
                status: 'fail'
                msg: err

    .then (user) ->
      # user is logged in
      reply.send
        status: 'ok'
        user: user
,
]