# node libraries
(require 'debug').enable 'routes'
logger = (require 'logging').default 'routes'
path = (require 'path')

# my libraries
FFTCGDB = (require './db')
FFTCGSESSION = (require './session')

# open fftcg.db (persistent data)
fftcgdb = new FFTCGDB path.resolve(__dirname, 'fftcg.db'), true
# open session storage (volatile data)
session = new FFTCGSESSION

JSONSCHEMA =
  user: ->
    body:
      login:    type: 'string'
      password: type: 'string'

    response:
      200:
        type: 'object'
        required: ['success']
        properties:
          success:  type: 'boolean'
          err:      type: 'string'
          user:
            type: 'object'
            required: ['user', 'login']
            properties:
              user:   type: 'number'
              login:  type: 'string'
        # user is required iff success
        # err is required otherwise
        if:
          properties:
            success:
              const: true
        then:
          required: ['user']
        else:
          required: ['err']


module.exports = [
# test
  url: '/test'
  method: 'POST'
  handler: (request, reply) ->
    logger.info 'Cookies', request.cookies
    logger.info 'Body', request.body
    logger.info 'Query', request.query
    logger.info 'Params', request.params

    reply.setCookie 'foo', 'foo'
    reply.send
      hello: 'world'
,
# register user
  url: '/user/register'
  method: 'POST'
  schema: JSONSCHEMA.user()

  handler: (request, reply) ->
    fftcgdb.register(request.body.login, request.body.password)
    .then (user) ->
      logger.info "OK registration '#{request.body.login}'"
      reply.send
        success: true
        user: user
      return

    .catch (err) ->
      logger.debug "FAIL registration '#{request.body.login}'"
      reply.send
        success: false
        err: err
,
# log in user
  url: '/user/login'
  method: 'POST'
  schema: JSONSCHEMA.user()

  handler: (request, reply) ->
    session_id = request.cookies.session ? ''

    new Promise (resolve) ->
      session.check session_id
      .then (user) ->
        # active session found
        logger.debug "OK '#{user.login}' resumed session '#{session_id}'"
        resolve user

      .catch ->
        fftcgdb.login request.body.login, request.body.password
        .then (user) ->
          # login successful: start new session
          session.start user
          .then (session_id) ->
            logger.info "OK '#{user.login}' created session '#{session_id}'"
            reply.setCookie 'session', session_id
            resolve user

        .catch (err) ->
          # login failed
          logger.info "FAIL login for '#{request.body.login}'"
          reply.send
            success: false
            err: err

    .then (user) ->
      # tell about the user who logged in
      reply.send
        success: true
        user: user
,
]